Regulære mangekantar

No skal me teikne nokre regulære mangekantar. Det vil seie mangekantar der avstanden mellom kvart hjørne er lik, altså er dei likesida, og vinkelen i kvart hjørne er lik, altså er dei likevinkla. Du lurar kanskje på korleis du skal få til dette. Hjørnene i ein regulær mangekant fordeler seg jamnt langs ein sirkel. Difor kan me bruke formlane for katetane til å reikne ut kor hjørna skal vere. Elles teiknar med figuren akkurat som alle andre mangekantar, slik du gjorde i ei anna oppgåve.

• Me startar med å teikne opp ein regulær (femkant).

  int KANTAR = 5;
  float vinkel = 360.0 / KANTAR;
  
  void setup() {
    size(600, 600);
  }
  
  void draw() {
    background(0);
  
    beginShape();
    for (int hjorne = 0; hjorne < KANTAR; hjorne++) {
      vertex(300 + cos(radians(vinkel * hjorne)) * 200,
             300 + sin(radians(vinkel * hjorne)) * 200);
    }
    endShape(CLOSE);
  }
  

  Inne i kallet på vertex ser du nokre nye utrekningar. Her brukar me tre nye funksjonar. Funksjonane sin og cos vart forklart lengre opp. Me brukar radians for å rekne om gradar til radianar, ei anna måleeining for vinklar.

  I dataprogram brukar sinus og cosinus vanlegvis radianar, så viss me vil jobbe med vinklar i gradar må me gjere denne konverteringa. Du ser at me har med ein variabel for vinkelen mellom kvart punkt, og den har me berekna i gradar ut frå at ein sirkel er 360°.

  Til slutt fortel CLOSE i endShape at siste kant i figuren skal setjast saman med den fyrste, altså at me lukkar og fyller figuren.

• Kva er talet 200 her? Kva skjer viss du endrar det til noko anna?

• Kva med talet 300?

• Kan du få snudd på femkanten så hjørnet som no peikar rett til høgre peikar rett opp?

• Viss du har fått femkanten til å peike opp, kan du leggje til ein variabel som du brukar til denne justeringa? Kan du bruke denne variabelen til å få femkanten til å snurre?

• Kan du styre kva veg femkanten peikar med musa eller tastaturet?

• Kva skjer viss du endrar KANTAR til ein annan verdi enn 5?

Regulære stjerner 1

Regulære stjerner med eit odde antal spissar kan teiknast nesten heilt likt som ein teiknar ein regulær mangekant. Dei er på ein måte ein slags variant av mangekantar. Viss du har teikna ei femkanta stjerne før, så har du kanskje lagt merke til at det liknar på ein femkant, men at du hoppar over eit hjørne når du teiknar streken mellom to spissar.

• Sidan me skal hoppe over eit hjørne kvar gong me teiknar opp neste spiss må me gangen vinkelen med 2. Endre kallet på vertex til:

  vertex(300 + cos(radians(vinkel * hjorne * 2)) * 200,
         300 + sin(radians(vinkel * hjorne * 2)) * 200);
  

  Kunne du ganga med 2 ein annan stad i koden og fått den same effekten?

• Kan du teikne ei sjukanta stjerne? Eller ei nikanta stjerne?

• Viss du har ei stjerne med fleire kantar enn fem, så kan du gange med andre tal enn to og få andre variantar av mangekanta stjerner. Prøv ulike tal for sju-, ni- og ellevekanta stjerner. Kva skjer når du hoppar over fleire kantar enn halvparten av antalet spissar?

Regulære stjerner 2

Stjerner med likt antal spissar (altså at det er eit partal) kan bli teikna som to regulære mangekantar med halvparten så mange hjørne som stjerna har spissar.

• Fjern ganging med to frå programmet som teiknar stjerner med eit odde antal spissar.

• Lag ein kopi av løkka som teiknar opp mangekanten, med beginShape(); og endShape(CLOSE);.

• I den nye løkka endrar du int hjorne = 0 til int hjorne = 1, slik at denne løkka teiknar kantane mellom dei odde hjørna.

• Endre hjorne++ til hjorne += 2 slik at me berre teiknar kantar mellom annakvart hjørne.

• Pass på at KANTAR blir sett til eit partal som er minst 6.